ie缓存视屏提取器

为啥不用xcopy？

天~~~视频

呵呵，我也经常提取ie缓存视频文件
晒晒我用的 ^_^
@echo off & rem 2011-01-22 23:15
title 提取指定时间段内的ie缓存文件
::提取某时间段内ie缓存文件,默认起始及结束时间为当前时间
::日期格式必须是 yyyy-mm-dd 样式
rem 输入时间段,格式必须是 yyyy-mm-dd-00:00 留空为当前日期、时间。
set "起始时间=2011-01-24-21:00"
set "结束时间="
rem 文件复制到此处，复制成功后文件名末尾会加上文件数量。
set "wjm=$ie缓存文件提取"
::删除文件名以 “$ie缓存文件提取” 开头的文件夹.
for /f "delims=" %%i in ('dir /b/ad "%wjm%*" 2^>nul') do rd /s /q "%%i"
md "%wjm%"
::提取当前日期
for /f "tokens=1-3 delims=./:\- " %%a in ("%date%") do (
    set /a y=%%a,m=100%%b%%100,d=100%%c%%100
)
set m=0%m%&set "d=0%d%"
set m=%m:~-2%&set "d=%d:~-2%"
::提取当前时间
for /f "tokens=1,2 delims=:" %%a in ("%time%") do (
    set /a xs=100%%a%%100,fz=100%%b%%100
)
set xs=0%xs%&set "fz=0%fz%"
::设置默认起始、结束时间为当前时间
if not defined 起始时间 set "起始时间=%y%-%m%-%d%-%xs:~-2%:%fz:~-2%"
if not defined 结束时间 set "结束时间=%y%-%m%-%d%-%xs:~-2%:%fz:~-2%"
::各类文件后缀名
set 视频=*.flv *.f4v *.hlv *.wmv *.mov *.mp4 *.mpg *.m4v *.avi *.rm *.rmvb *.asf
set 音频=*.wav *.mp3 *.m4a *.mid *.wma *.ra *.ogg *.aac *.amr *.ape *.cue
set 压缩=*.rar *.zip *.r0? *.gz *.jar *.z *.7z
set 图片=*.bmp *.jpg *.jpeg *.gif *.png
::获取ie缓存文件夹位置
set "zcb=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
for /f "tokens=1* delims=Z" %%i in ('reg query "%zcb%" /v cache') do set "weizi=%%j"
set "hc=%weizi:~1%"
for /f "tokens=* delims= " %%i in ("%hc%") do set "hc=%%i"
if not exist "%hc%\" echo 没有找到ie缓存文件夹%hc%位置&goto end
::提取文件
set /a n=0
for /r "%hc%" %%i in (%视频%) do (
    for /f "tokens=1,2 delims= " %%j in ("%%~ti") do (
       if %%j-%%k geq %起始时间% if %%j leq %结束时间% (
             copy /y "%%i" "%wjm%"
             echo %%i /%%k/
             set /a n+=1
        )
     )
)
if %n% neq 0 ren "%wjm%" "%wjm% %n%"&set "wjm=%wjm% %n%"
start "" "%wjm%"
exit
:end
pause


set "zcb=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders"
用注册表的方法确实更好，而且还解决了兼容性的问题。

我只设置了250m的缓存空间，所以时间……

话说这是Win7出来以前写的...也适用于win7呵~
@echo off
color 0a
title ★☆缓存文件提取器☆★ [新年特别版 For Vista]
mode con cols=52 lines=20
echo.
echo.
echo ----------------------------------------------------
echo.
echo.
echo -----------★☆--缓存文件提取器--☆★---------------
echo.
echo.
echo ----------------------------------------------------
echo.
echo.
echo.
echo.
echo.
set /p t=请输入要提取的文件的扩展名: .
cls
echo.
echo.
echo ----------------------------------------------------
echo.
echo.
echo -----------★☆--缓存文件提取器--☆★---------------
echo.
echo.
echo ----------------------------------------------------
echo.
echo.
echo   (=^^_^^=) 正在提取指定的缓存文件,请稍等.........
echo.
echo.
echo.
ping -n 2 127.1>nul
pushd %userprofile%\desktop\ & md 提取的%t%文件 >nul 2>nul
for /f "delims=" %%i in ('dir /s /a /b "%userprofile%\AppData\Local\Microsoft\Windows\TEMPOR~1"\*.%t%') do (
copy /y "%%i"    "%userprofile%\desktop\提取的%t%文件\"  
) >nul
cd /d %userprofile%\desktop\提取的%t%文件
setlocal enabledelayedexpansion
set /a k=0
for /f "tokens=*" %%a in ('dir "*.%t%" /b') do (
set /a k+=1
ren "%%a" "第!k!个文件.%t%"
)>nul
start explorer "%userprofile%\Desktop\提取的%t%文件"
exit

再放个XP版的~~ 话说都一样 就是改了下路径~
@echo off
color 0a
title ★☆缓存文件提取器☆★ [新年特别版 For XP]
mode con cols=50 lines=20
:x
cls
echo.
echo.
echo --------------------------------------------------
echo.
echo.
echo ----------★☆--缓存文件提取器--☆★--------------
echo.
echo.
echo --------------------------------------------------
echo.
echo.
echo.
echo.
echo.
set /p t=请输入要提取的文件的扩展名: .
cls
echo.
echo.
echo --------------------------------------------------
echo.
echo.
echo ----------★☆--缓存文件提取器--☆★--------------
echo.
echo.
echo --------------------------------------------------
echo.
echo.
echo   (=^^_^^=) 正在提取指定的缓存文件,请稍等.........
echo.
echo.
echo.
ping -n 2 127.1>nul
pushd %userprofile%\桌面\ & md 提取的%t%文件 >nul 2>nul
for /f "delims=" %%i in ('dir /s /a-d /b "%userprofile%\locals~1\*.%t%"') do (
copy /y "%%i"    "%userprofile%\桌面\提取的%t%文件\"  
) >nul
cd /d %userprofile%\桌面\提取的%t%文件
setlocal enabledelayedexpansion
set /a k=0
for /f "tokens=*" %%a in ('dir "*.%t%" /b') do (
set /a k+=1
ren "%%a" "第!k!个文件.%t%"
)>nul
start explorer "%userprofile%\桌面\提取的%t%文件"
goto x
exit

谢谢了

貌似大神都不用这些东西，操作很麻烦，而且准确率也有待提高啊，特别是当缓存的视频文件很多时

回复：10楼
那请问大神用什么

我意思是 懂得原理了还是手动操作更精确一些，毕竟这个不是什么很复杂的事情